Uma abordagem é usar o Oracle's Advanced Queuing . Para isso, você precisa configurar uma fila (e uma tabela de filas) e escrever um procedimento PL/SQL que aguarde a próxima mensagem na fila.
O lado C++ então chama o procedimento PL/SQL, que retorna quando o próximo evento ocorre.
No lado da Oracle, você precisará usar DBMS_SCHEDULER ou um recurso semelhante para criar o evento , ou seja, inserir uma nova mensagem na fila no momento apropriado.
Ainda é uma abordagem de votação. No entanto, não há absolutamente nenhuma atividade entre dois eventos.
Atualização:
Aqui está um código de exemplo.
Configuração inicial da fila (a mensagem contém um valor numérico e de texto):
grant AQ_ADMINISTRATOR_ROLE to appuser;
grant EXECUTE ON DBMS_AQ to appuser;
grant EXECUTE ON DBMS_AQ to appuser;
CREATE TYPE sample_payload_type AS OBJECT
(
cmd VARCHAR2(20),
id NUMBER
);
BEGIN
DBMS_AQADM.CREATE_QUEUE_TABLE (
queue_table => 'sample_queue_table',
queue_payload_type => 'sample_payload_type',
sort_list => 'ENQ_TIME',
compatible => '10.0'
);
END;
/
BEGIN
DBMS_AQADM.CREATE_QUEUE (
queue_name => 'sample_queue',
queue_table => 'sample_queue_table'
);
DBMS_AQADM.START_QUEUE (
queue_name => 'sample_queue'
);
END;
/
Cabeçalho do pacote:
create or replace package sample_queue_pkg
as
procedure get_next_msg(
i_max_wait number
,o_cmd out varchar2
,o_id out number
);
procedure put_msg(
i_cmd varchar2
,i_id number
);
end sample_queue_pkg;
/
Corpo do pacote:
create or replace package body sample_queue_pkg
as
procedure get_next_msg(
i_max_wait number
,o_cmd out varchar2
,o_id out number
)
is
dequeue_options dbms_aq.dequeue_options_t;
message_properties dbms_aq.message_properties_t;
message_handle RAW(16);
message sample_payload_type;
NO_MESSAGE_RECEIVED EXCEPTION;
PRAGMA EXCEPTION_INIT(NO_MESSAGE_RECEIVED, -25228);
begin
dequeue_options.wait := i_max_wait;
DBMS_AQ.DEQUEUE (
queue_name => 'appuser.sample_queue',
dequeue_options => dequeue_options,
message_properties => message_properties,
payload => message,
msgid => message_handle
);
o_cmd := message.cmd;
o_id := message.id;
exception
when NO_MESSAGE_RECEIVED then
o_cmd := null;
o_id := null;
end get_next_msg;
procedure put_msg(
i_cmd varchar2
,i_id number
)
is
enqueue_options dbms_aq.enqueue_options_t;
message_properties dbms_aq.message_properties_t;
message_handle RAW(16);
message sample_payload_type;
message_id NUMBER;
begin
message := sample_payload_type(i_cmd, i_id);
DBMS_AQ.ENQUEUE(
queue_name => 'appuser.sample_queue',
enqueue_options => enqueue_options,
message_properties => message_properties,
payload => message,
msgid => message_handle
);
end put_msg;
end sample_queue_pkg;
/
O servidor de banco de dados pode enviar uma mensagem usando o seguinte código:
sample_queue_pkg.put_msg('run_task', 8234);
commit;
O servidor C++ pode esperar pela mensagem (e recebê-la) chamando o
sample_queue_pkg.get_next_msg armazenado . O parâmetro i_max_wait especifica o tempo máximo de espera pela próxima mensagem em segundos. Você provavelmente deseja implementar um loop que aguarda a próxima mensagem e a processa até receber um sinal de que o servidor está prestes a encerrar. 
