Como adicionar restrição de chave primária a colunas de identidade para todas as tabelas no banco de dados SQL Server

Cenário:

Você está trabalhando como desenvolvedor do SQL Server. Você tem este requisito em que você tem que criar restrição de chave primária em todas as colunas de identidade em todas as tabelas no banco de dados SQL Server, se não existir.
O nome da chave primária deve ser Pk_SchemaName_TableName_ColumnName.

Solução:

Antes de tudo, precisamos obter a lista de tabelas que possuem coluna de identidade e a restrição de chave primária não é criada nelas. estaremos usando tabelas do sistema e visualizações do sistema para obter todas as tabelas com colunas de identidade que não possuem restrições de chave primária.
Então vamos usar o Cursor com SQL dinâmico para gerar a instrução Alter para a tabela para adicionar a restrição de chave primária e executar o script.

USE YourDatabaseName
GO

--Declare Variables
DECLARE @DatabaseName AS VARCHAR(128)
DECLARE @SchemaName AS VARCHAR(128)
DECLARE @TableName AS VARCHAR(128)
DECLARE @ColumnName AS VARCHAR(128)

DECLARE CUR CURSOR
FOR
--Get list of tables with Identity Column
--on which have no Primary Key
SELECT DB_Name() AS DatabaseName
    ,Schema_Name(Schema_id) AS TableSchema
    ,OBJECT_NAME(c.OBJECT_ID) AS TableName
    ,c.NAME AS ColumnName
FROM sys.columns c
INNER JOIN sys.tables t ON c.object_id = t.object_id
WHERE is_identity = 1
    AND type_desc = 'USER_TABLE'

EXCEPT

SELECT TC.Table_Catalog AS DatabaseName
    ,TC.Table_Schema AS TableSchema
    ,TC.Table_Name AS TableName
    ,CCU.Column_Name AS ColumnName
FROM information_Schema.Table_Constraints TC
INNER JOIN Information_Schema.constraint_column_usage CCU

ON TC.Constraint_Name = CCU.Constraint_Name
    AND TC.Table_Name = CCU.Table_Name
WHERE Constraint_Type = 'PRIMARY KEY'

OPEN Cur

FETCH NEXT
FROM Cur
INTO @DatabaseName
    ,@SchemaName
    ,@TableName
    ,@ColumnName

WHILE @@FETCH_STATUS = 0
BEGIN
    --Build dynamic sql for each database 
    DECLARE @SQL VARCHAR(MAX) = NULL

    SET @SQL = 'Alter Table [' + @SchemaName + '].[' + @TableName + ']' + CHAR(10)
    SET @SQL += 'Add Constraint [Pk_' + @SchemaName

+ '_' + @TableName

             + '_' + @ColumnName + '] '
    SET @SQL += 'Primary Key ([' + @ColumnName + '])'

    EXEC (@SQL)

    PRINT @SQL

    FETCH NEXT
    FROM Cur
    INTO @DatabaseName
        ,@SchemaName
        ,@TableName
        ,@ColumnName
END

CLOSE Cur

DEALLOCATE Cur

Se você quiser apenas gerar as instruções alter para adicionar a restrição de chave primária, você pode adicionar comentários à parte Exec(@SQL). Se não quiser adicionar a parte do nome do esquema à restrição de chave primária, você pode remover @SchemaName.
Eu executei a consulta acima e ela criou a restrição de chave primária nas colunas de identidade onde estava faltando.

Alterar scripts gerados por script para adicionar restrição de chave primária às colunas de identidade

Verifiquei as tabelas e as restrições de chave primária foram criadas com sucesso.

Como criar restrição de chave primária em colunas de identidade no banco de dados SQL Server

Como adicionar restrição de chave primária a colunas de identidade para todas as tabelas no banco de dados SQL Server - SQL Server / TSQL Tutorial Part 63

Cenário:

Solução: