Não faça loops dentro de loops em PL/SQL para isso - use SQL para fornecer os dados prontos para uso.
Primeiro, criamos sua tabela com alguns dados de teste (estou supondo tipos de dados - você substitui pelos seus):
create table product_master (
product_no varchar2(10)
, product_holder varchar2(10)
, product_catalogue varchar2(10)
)
/
insert into product_master values ('1', 'SMITH', 'TEMP')
/
insert into product_master values ('2', 'SMITH', 'TEMP')
/
insert into product_master values ('3', 'HARRY', 'ARCH')
/
insert into product_master values ('4', 'TOM' , 'DEPL')
/
commit
/
O que queremos enviar para
mail_send procedimento para cada product_holder é uma coleção (array) contendo product_no e product_catalogue . Então, primeiro um tipo que contém esses dois elementos:create type t_prod_cat_no as object (
product_no varchar2(10)
, product_catalogue varchar2(10)
)
/
E, em seguida, um tipo de tabela aninhada (tipo de coleção) desse tipo:
create type t_prod_cat_no_table as
table of t_prod_cat_no
/
O procedimento
mail_send então deve aceitar o product_holder e o tipo de coleção:create or replace procedure mail_send (
p_parameter in varchar2
, p_product_holder in varchar2
, p_product_cats_nos in t_prod_cat_no_table
)
is
begin
dbms_output.put_line('-- BEGIN '||p_parameter||' --');
dbms_output.put_line('Dear '||p_product_holder);
dbms_output.put_line('Your products are:');
for i in 1..p_product_cats_nos.count loop
dbms_output.put_line(
'Catalogue: '||p_product_cats_nos(i).product_catalogue||
' - No: '||p_product_cats_nos(i).product_no
);
end loop;
end mail_send;
/
(Eu apenas uso dbms_output para simular a construção de um email.)
Então você pode no SQL fazer um
group by product_holder e deixe o SQL gerar a coleção contendo os dados:begin
for holder in (
select pm.product_holder
, cast(
collect(
t_prod_cat_no(pm.product_no,pm.product_catalogue)
order by pm.product_catalogue
, pm.product_no
) as t_prod_cat_no_table
) product_cats_nos
from product_master pm
group by pm.product_holder
order by pm.product_holder
) loop
mail_send(
'PRODMASTER'
, holder.product_holder
, holder.product_cats_nos
);
end loop;
end;
/
A saída do bloco acima será:
-- BEGIN PRODMASTER --
Dear HARRY
Your products are:
Catalogue: ARCH - No: 3
-- BEGIN PRODMASTER --
Dear SMITH
Your products are:
Catalogue: TEMP - No: 1
Catalogue: TEMP - No: 2
-- BEGIN PRODMASTER --
Dear TOM
Your products are:
Catalogue: DEPL - No: 4
Fazendo isso em SQL com um
GROUP BY fornece tudo em uma única chamada de PL/SQL para SQL, o que é muito mais eficiente do que a primeira chamada para obter o conjunto distinto de product_holder , faça um loop sobre isso e, em seguida, uma chamada por product_holder para obter os produtos para cada titular. ATUALIZAR:
Adicionado
order by para a collect função no código acima para mostrar que você tem controle sobre a ordem em que os dados são preenchidos na coleção. 
