Há dois usos para RAISE_APPLICATION_ERROR. A primeira é substituir as mensagens de exceção genéricas do Oracle por nossas próprias mensagens mais significativas. A segunda é criar condições de exceção próprias, quando a Oracle não as lançaria.
O procedimento a seguir ilustra ambos os usos. Ele impõe uma regra de negócios de que novos funcionários não podem ser contratados no futuro. Ele também substitui duas exceções do Oracle. Um é DUP_VAL_ON_INDEX, que é gerado por uma chave exclusiva em
EMP(ENAME) . A outra é uma exceção definida pelo usuário lançada quando a chave estrangeira entre EMP(MGR) e EMP(EMPNO) é violado (porque um gerente deve ser um funcionário existente). create or replace procedure new_emp
( p_name in emp.ename%type
, p_sal in emp.sal%type
, p_job in emp.job%type
, p_dept in emp.deptno%type
, p_mgr in emp.mgr%type
, p_hired in emp.hiredate%type := sysdate )
is
invalid_manager exception;
PRAGMA EXCEPTION_INIT(invalid_manager, -2291);
dummy varchar2(1);
begin
-- check hiredate is valid
if trunc(p_hired) > trunc(sysdate)
then
raise_application_error
(-20000
, 'NEW_EMP::hiredate cannot be in the future');
end if;
insert into emp
( ename
, sal
, job
, deptno
, mgr
, hiredate )
values
( p_name
, p_sal
, p_job
, p_dept
, p_mgr
, trunc(p_hired) );
exception
when dup_val_on_index then
raise_application_error
(-20001
, 'NEW_EMP::employee called '||p_name||' already exists'
, true);
when invalid_manager then
raise_application_error
(-20002
, 'NEW_EMP::'||p_mgr ||' is not a valid manager');
end;
/
Como fica:
SQL> exec new_emp ('DUGGAN', 2500, 'SALES', 10, 7782, sysdate+1)
BEGIN new_emp ('DUGGAN', 2500, 'SALES', 10, 7782, sysdate+1); END;
*
ERROR at line 1:
ORA-20000: NEW_EMP::hiredate cannot be in the future
ORA-06512: at "APC.NEW_EMP", line 16
ORA-06512: at line 1
SQL>
SQL> exec new_emp ('DUGGAN', 2500, 'SALES', 10, 8888, sysdate)
BEGIN new_emp ('DUGGAN', 2500, 'SALES', 10, 8888, sysdate); END;
*
ERROR at line 1:
ORA-20002: NEW_EMP::8888 is not a valid manager
ORA-06512: at "APC.NEW_EMP", line 42
ORA-06512: at line 1
SQL>
SQL> exec new_emp ('DUGGAN', 2500, 'SALES', 10, 7782, sysdate)
PL/SQL procedure successfully completed.
SQL>
SQL> exec new_emp ('DUGGAN', 2500, 'SALES', 10, 7782, sysdate)
BEGIN new_emp ('DUGGAN', 2500, 'SALES', 10, 7782, sysdate); END;
*
ERROR at line 1:
ORA-20001: NEW_EMP::employee called DUGGAN already exists
ORA-06512: at "APC.NEW_EMP", line 37
ORA-00001: unique constraint (APC.EMP_UK) violated
ORA-06512: at line 1
Observe a saída diferente das duas chamadas para RAISE_APPLICATION_ERROR no bloco EXCEPTIONS. Definir o terceiro argumento opcional como TRUE significa que RAISE_APPLICATION_ERROR inclui a exceção de acionamento na pilha, que pode ser útil para diagnóstico.
Há mais informações úteis no PL/SQL User's Guide.
