Menu de acesso suspenso do TreeView ImageCombo

Introdução.

Os links da sessão do Tutorial de controle TreeView.

1. Tutorial de controle do Microsoft TreeView
2. Criando menu de acesso com controle TreeView
3. Atribuindo imagens ao controle TreeView
4. Atribuindo imagens ao TreeView Control-2
5. Marque de seleção de controle do TreeView Adicionar nós de exclusão

A visualização de demonstração de ambas as ImageComboBoxes expandida.

Os dados de origem do ImageComboBox suspenso.

Preparando-se para o design do formulário do menu suspenso.

1. Faça uma cópia da ImageList Controle de frmMenu2 Form e cole-o em um novo formulário, digamos frmMenu3Combo .
   Este controle de lista de imagens tem imagens que carregamos manualmente do computador em nossa sessão de tutorial anterior. Você pode abrir sua Folha de Propriedades e verificar as Imagens e sua Chave Nomes. Clique com o botão direito do mouse no controle ImageList, realce ImageListCtl Object e selecione a opção Propriedades.
   
2. 
   O controle ImageComboBox colocado no lado esquerdo do formulário é para o menu suspenso, com o nome:imgCombo1 . Encontre o Controle do Microsoft ImageComboBox dos Controles ActiveX grupo e coloque-o no formulário. Altere o nome do controle para imgCombo1 .
   
3. 
   Crie outro controle ImageComboBox ao lado direito, com o nome imgCombo2 . A segunda ImageComboBox que usaremos para exibir as imagens e seus nomes de chave, da ImageList0 Controle, como uma lista suspensa.
   
4. 
   Adicione um controle Label acima do segundo controle ImageComboBox e altere sua legenda para Lista de imagens.
   

A listagem de imagens no controle Image-Combo-Box.

Dim imgcombo1 As MSComctlLib.ImageCombo
Dim imgCombo2 As MSComctlLib.ImageCombo
Dim objimgList As MSComctlLib.ImageList
Const KeyPrfx As String = "X"

Private Sub Form_Load()

Set objimgList = Me.ImageList0.Object

cboImageList 'load imagelist-combo

'CreateMenu 'Create Drop-Down Menu
 
End Sub

Private Sub cboImageList()
Dim j As Integer
Dim strText As String

Set imgCombo2 = Me.ImageCombo2.Object
imgCombo2.ImageList = objimgList

For j = 1 To objimgList.ListImages.Count
    strText = objimgList.ListImages(j).Key
    imgCombo2.ComboItems.Add , , strText,j,,j
Next
    imgCombo2.ComboItems(1).Selected = True
End Sub

Revisão do código VBA.

imgCombo2.ComboItems.Add [Index],[Key],[Text],[Image],[SelImage],[Indentation]

Lista de imagens com recuo incrementado Configuração de parâmetros.

O código VBA do menu suspenso do projeto.

Private Sub CreateMenu()
Dim db As DAO.Database
Dim rst As DAO.Recordset
Dim strSQL As String
Dim strKey As String
Dim strText As String
Dim typ As Integer

Set imgcombo1 = Me.ImageCombo1.Object
imgcombo1.ImageList = objimgList

strSQL = "SELECT ID, Desc, PID, Type,Macro,Form,Report FROM Menu;"

Set db = CurrentDb
Set rst = db.OpenRecordset(strSQL, dbOpenDynaset)

Do While Not rst.EOF And Not rst.BOF
    If Len(Trim(Nz(rst!PID, ""))) = 0 Then
        strKey = KeyPrfx & CStr(rst!ID)
        strText = rst!Desc
        imgcombo1.ComboItems.Add , strKey, strText, 1, 2, 1 ' image index 1,2([image],[selectedimage])
        'imgcombo1.ComboItems.Add , strKey, strText, "folder_close", "folder_open", 1
    Else
        strKey = KeyPrfx & CStr(rst!ID)
        strText = rst!Desc
        imgcombo1.ComboItems.Add , strKey, strText, 4, 5, 4 'last param is spacing
        'imgcombo1.ComboItems.Add , strKey, strText, "left_arrow", "right_arrow", 4
     
        'Check for the presense of Type Code
        If Nz(rst!Type, 0) > 0 Then
                typ = rst!Type
                With imgcombo1.ComboItems
            Select Case typ
                'save type Code & Form/Report/Macro Name in Tag Property
                Case 1
                    .Item(strKey).Tag = typ & rst!Form
                Case 2
                    .Item(strKey).Tag = typ & rst!Report
                Case 3
                    .Item(strKey).Tag = typ & rst!Macro
            End Select
                End With
        End If
        
    End If
    rst.MoveNext
Loop
rst.Close
imgcombo1.ComboItems.Item(1).Selected = True
End Sub

Private Sub ImageCombo1_Click()
Dim strObject As String
Dim strTag As String
Dim typ As Integer

strTag = ImageCombo1.SelectedItem.Tag
typ = Val(strTag)
strObject = Mid(strTag, 2)

Select Case typ
    Case 1
        DoCmd.OpenForm strObject, acNormal
    Case 2
        DoCmd.OpenReport strObject, acViewPreview
    Case 3
        DoCmd.RunMacro strObject
End Select

End Sub

A sub-rotina CreateMenu().

imgcombo1.ComboItems.Add , strKey, strText, 1, 2, 1

OBJETO DO DICIONÁRIO

1. Noções básicas de objetos do dicionário
2. Noções básicas de objetos do dicionário-2
3. Classificação de chaves e itens de objetos de dicionário
4. Exibir registros do dicionário
5. Adicionar objetos de classe como itens de dicionário
6. Atualizar item do dicionário de objetos de classe