Uma função PL/SQL pode retornar uma tabela aninhada. Desde que declaremos a tabela aninhada como um tipo SQL, podemos usá-la como fonte de uma consulta, usando o a função TABLE() .
Aqui está um tipo e uma tabela aninhada construída a partir dele:
SQL> create or replace type emp_dets as object (
2 empno number,
3 ename varchar2(30),
4 job varchar2(20));
5 /
Type created.
SQL> create or replace type emp_dets_nt as table of emp_dets;
2 /
Type created.
SQL>
Aqui está uma função que retorna essa tabela aninhada ...
create or replace function get_emp_dets (p_dno in emp.deptno%type)
return emp_dets_nt
is
return_value emp_dets_nt;
begin
select emp_dets(empno, ename, job)
bulk collect into return_value
from emp
where deptno = p_dno;
return return_value;
end;
/
... e é assim que funciona:
SQL> select *
2 from table(get_emp_dets(10))
3 /
EMPNO ENAME JOB
---------- ------------------------------ --------------------
7782 CLARK MANAGER
7839 KING PRESIDENT
7934 MILLER CLERK
SQL>
Tipos SQL nos oferecem muitas funcionalidades e nos permitem construir APIs bastante sofisticadas em PL/SQL. Saiba mais .
