Pelo menos você perdeu uma definição de tabela no segundo caso. Esta afirmação:
create or replace TYPE tbl_list2 IS OBJECT (l_owner VARCHAR2(64),l_name VARCHAR2(64));
declara apenas o tipo de objeto (ou registro), não uma tabela.
Então você precisa fazer isso em 2 etapas:
create or replace TYPE tbl_list_rec IS OBJECT (l_owner VARCHAR2(64),l_name VARCHAR2(64));
/
create or replace TYPE tbl_list2 as table of tbl_list_rec;
/
Depois disso, você precisa de algumas correções de sintaxe no script:
declare
l_object tbl_list2;
i number;
begin
-- for list initialization it must be filled with constructed objects
l_object := tbl_list2( tbl_list_rec('','') );
for i in 1..100000 loop
-- 1. select values to variable
-- 2. Fix constructor for list
select
l_object MULTISET UNION DISTINCT tbl_list2(tbl_list_rec('myOwner','MyTable'))
into
l_object
from
dual;
end loop;
for i in l_object.first .. l_object.last loop
-- output separate fields, there are now default conversion from
-- user-defined objects to varchar2.
dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
end loop;
end;
/
ATUALIZAÇÃO
Solução acima relativamente lenta devido ao grande número de trocas de contexto. Mas a comparação de instâncias de tipos de objetos complexos não pode ser feita diretamente em PL/SQL sem algum trabalho adicional.
Para permitir que o Oracle saiba se as instâncias de objetos são iguais ou diferentes, precisamos definir método de mapeamento ou ordenação para tipo de objeto . Ambos os tipos de métodos não são permitidos, portanto, é necessário escolher um método adequado. Os métodos MAP são mais rápidos e não há necessidade de ordenação no nosso caso, então vá em frente:
create or replace TYPE tbl_list_rec2 AS OBJECT (
l_owner VARCHAR2(64),
l_name VARCHAR2(64),
map member function get_key return varchar2
);
/
Implementação:
create or replace TYPE BODY tbl_list_rec2 AS
map member function get_key return varchar2
is
begin
return l_owner||chr(1)||l_name;
end;
end;
/
Depois disso, é possível testar objetos para igualdade no código PL/SQL como simples
varchar2 no primeiro exemplo da pergunta:declare
l_object tbl_list2a;
i number;
begin
l_object := tbl_list2a( tbl_list_rec2('','') );
for i in 1..100000 loop
l_object := l_object MULTISET UNION DISTINCT tbl_list2a(tbl_list_rec2('myOwner','MyTable'));
end loop;
for i in l_object.first.. l_object.last loop
dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
end loop;
end;
/
