Inserindo no Oracle e recuperando o ID de sequência gerado

Expandindo um pouco as respostas de @Guru e @Ronnis, você pode ocultar a sequência e torná-la mais parecida com um incremento automático usando um gatilho, e ter um procedimento que faça a inserção para você e retorne o ID gerado como uma saída parâmetro.

create table batch(batchid number,
    batchname varchar2(30),
    batchtype char(1),
    source char(1),
    intarea number)
/

create sequence batch_seq start with 1
/

create trigger batch_bi
before insert on batch
for each row
begin
    select batch_seq.nextval into :new.batchid from dual;
end;
/

create procedure insert_batch(v_batchname batch.batchname%TYPE,
    v_batchtype batch.batchtype%TYPE,
    v_source batch.source%TYPE,
    v_intarea batch.intarea%TYPE,
    v_batchid out batch.batchid%TYPE)
as
begin
    insert into batch(batchname, batchtype, source, intarea)
    values(v_batchname, v_batchtype, v_source, v_intarea)
    returning batchid into v_batchid;
end;
/

Você pode então chamar o procedimento em vez de fazer uma inserção simples, por exemplo. de um bloco anônimo:

declare
    l_batchid batch.batchid%TYPE;
begin
    insert_batch(v_batchname => 'Batch 1',
        v_batchtype => 'A',
        v_source => 'Z',
        v_intarea => 1,
        v_batchid => l_batchid);
    dbms_output.put_line('Generated id: ' || l_batchid);

    insert_batch(v_batchname => 'Batch 99',
        v_batchtype => 'B',
        v_source => 'Y',
        v_intarea => 9,
        v_batchid => l_batchid);
    dbms_output.put_line('Generated id: ' || l_batchid);
end;
/

Generated id: 1
Generated id: 2

Você pode fazer a chamada sem um bloqueio anônimo explícito, por exemplo. do SQL*Plus:

variable l_batchid number;
exec insert_batch('Batch 21', 'C', 'X', 7, :l_batchid);

... e use a variável de ligação :l_batchid para se referir ao valor gerado posteriormente:

print l_batchid;
insert into some_table values(:l_batch_id, ...);