Oracle PL/SQL:Exportar dados de uma tabela para CSV

Saiba como usar o UTL_FILE pacote para exportar dados de uma tabela para o arquivo CSV no Oracle PL/SQL.

No Oracle, o pacote UTL_FILE contém muitos procedimentos e funções para escrever um arquivo de texto. Abaixo estão os detalhes da sintaxe e as etapas necessárias para escrever um arquivo:

Sintaxe e etapas para gravar um arquivo usando UTL_FILE

-- Declare a variable to store file type
n_file UTL_FILE.FILE_TYPE;
-- Open the file in Begin section, it will open the file and return the file handle into the variable n_file
n_file := UTL_FILE.FOPEN('DIR_OBJ', 'YourCSVFileName.csv', 'w', 4000);
-- Write a single or multiple lines
UTL_FILE.PUT_LINE(n_file, 'abc, xyz, xxx');
-- Close the file
UTL_FILE.FCLOSE(n_file);

Exemplo básico

Declare
   n_file Utl_File.File_Type;
Begin
   -- The directory object MY_DIR must be exist or create a new one
   n_file := Utl_File.Fopen('MY_DIR', 'myfile.csv', 'w', '4000');

   Utl_File.Put_Line(n_file, 'First line.');
   Utl_File.Put_Line(n_file, 'Second line.');
   Utl_File.Put_Line(n_file, 'Third line.');

   Utl_File.Fclose(n_file);
End;

Como mencionei no exemplo acima, o objeto de diretório MY_DIR deve existir. O objeto de diretório no Oracle é uma referência ao diretório físico no servidor. Veja a seguir um exemplo de criação de um objeto de diretório no Oracle:

-- Windows example
CREATE OR REPLACE DIRECTORY CSVDIR AS 'd:\oracle\csvfiles';
-- Linux example
CREATE OR REPLACE DIRECTORY CSVDIR AS '/usr1/oracle/csvfiles';

Para saber mais sobre o objeto de diretório no Oracle, consulte este link.

Exportar dados de uma tabela para CSV no exemplo Oracle

Veja a seguir um exemplo de procedimento armazenado no Oracle, que exportará os dados da tabela EMP para um arquivo CSV:

Create Or Replace Procedure exp_emp_data Is

    n_file     utl_file.file_type;
    v_string   Varchar2(4000);
   
  -- get the data using cursor 
  Cursor c_emp Is
    Select
        empno,
        ename,
        deptno,
        sal,
        comm
    From
        emp;

Begin
    n_file := utl_file.fopen('CSVDIR', 'empdata.csv', 'w', 4000);

-- if you do not want heading then remove below two lines
    v_string := 'Emp Code, Emp Name, Dept, Salary, Commission';
    utl_file.put_line(n_file, v_string);
    
    -- open the cursor and concatenate fields using comma
    For cur In c_emp Loop
        v_string := cur.empno
                    || ','
                    || cur.ename
                    || ','
                    || cur.deptno
                    || ','
                    || cur.sal
                    || ','
                    || cur.comm;
        
        -- write each row
        utl_file.put_line(n_file, v_string);
    End Loop;
    
    -- close the file
    utl_file.fclose(n_file);
Exception
    When Others Then
        -- on error, close the file if open
        If utl_file.is_open(n_file) Then
            utl_file.fclose(n_file);
        End If;
End;

Agora que seu procedimento armazenado foi criado, execute-o para exportar os dados:

Begin
    exp_emp_data;
End;

Tutoriais relacionados:

Utilitário:gerar procedimento PL/SQL para exportar dados de uma tabela