Codificação clássica ASP, MySQL ou ODBC UTF8

Você tem uma chance para letras eslovenas de acordo com este mapeamento e um trecho do artigo wiki do Windows-1252 :

Aqui estão as coisas a fazer:

Use arquivos codificados UTF-8 (sem BOM) contra a possibilidade de conter texto codificado permanentemente. (✔ já feito)
Especifique UTF-8 para o conjunto de caracteres de resposta com ASP no lado do servidor ou com metatags no lado do cliente. (✔ já feito)
Diga ao MySQL Server que seus comandos estão em charset utf-8 e você espera conjuntos de resultados codificados em utf-8. Adicione uma instrução inicial à string de conexão:...;stmt=SET NAMES 'utf8';...
Defina o Response.CodePage como 1252.

Eu testei o script a seguir e funciona como um encanto.

DDL: http://sqlfiddle.com/#!8/c2c35/1

ASP:

<%@Language=VBScript%>
<% 
Option Explicit

Response.CodePage = 1252
Response.LCID = 1060
Response.Charset = "utf-8"

Const adCmdText = 1, adVarChar = 200, adParamInput = 1, adLockOptimistic = 3

Dim Connection
Set Connection = Server.CreateObject("Adodb.Connection")
    Connection.Open "Driver={MySQL ODBC 3.51 Driver};Server=localhost;Database=myDb;User=myUsr;Password=myPwd;stmt=SET NAMES 'utf8';"
    
If Request.Form("name").Count = 1 And Len(Request.Form("name")) Then 'add new
    Dim rsAdd
    Set rsAdd = Server.CreateObject("Adodb.Recordset")
        rsAdd.Open "names", Connection, ,adLockOptimistic
        rsAdd.AddNew
        rsAdd("name").Value = Left(Request.Form("name"), 255)
        rsAdd.Update
        rsAdd.Close
    Set rsAdd = Nothing
End If

Dim Command
Set Command = Server.CreateObject("Adodb.Command")
    Command.CommandType = adCmdText
    Command.CommandText = "Select name From `names` Order By id Desc"
    
    If Request.QueryString("name").Count = 1 And Len(Request.QueryString("name")) Then
        Command.CommandText = "Select name From `names` Where name = ? Order By id Desc"
        Command.Parameters.Append Command.CreateParameter(, adVarChar, adParamInput, 255, Left(Request.QueryString("name"), 255))
    End If
    
    Set Command.ActiveConnection = Connection
    With Command.Execute
        While Not .Eof
            Response.Write "<a href=""?name=" & .Fields("name").Value & """>" & .Fields("name").Value & "</a><br />"
            .MoveNext
        Wend
        .Close
    End With
    
    Set Command.ActiveConnection = Nothing
    Set Command = Nothing
    
Connection.Close
%><hr />
<a href="?">SHOW ALL</a><hr />
<form method="post" action="<%=Request.ServerVariables("SCRIPT_NAME")%>">
Name : <input type="text" name="name" maxlength="255" /> <input type="submit" value="Add" />
</form>

Como última observação:

Quando você precisa aplicar codificação html a strings buscadas no banco de dados, você não deve mais usar Server.HTMLEncode devido a Response.Codepage ser 1252 no lado do servidor e como Server.HTMLEncode é uma página de código de contexto dependente, isso causará saídas sem sentido.
Então você precisará escrever seu próprio codificador html para lidar com o caso.

Function MyOwnHTMLEncode(ByVal str)
    str = Replace(str, "&", "&amp;")
    str = Replace(str, "<", "&lt;")
    str = Replace(str, ">", "&gt;")
    str = Replace(str, """", "&quot;")
    MyOwnHTMLEncode = str
End Function
'Response.Write MyOwnHTMLEncode(rs("myfield").value)