Perl e XPath:entradas ausentes na tabela do banco de dados

• 
  Você deve prepare o INSERT INTO instrução SQL e, em seguida, execute isso dentro do laço. do tem uma sobrecarga muito maior
  
• 
  O // ( descendant-or-self::node() ) A construção XPath é cara e você deve reservá-la para casos em que você não tem ideia de onde o elemento estará dentro do documento, o que é muito raro. Neste caso, a row1 os elementos estão em /database/row1s/row1 e a row2 os elementos estão em row2s/row2 em relação a isso
  
• 
  É muito mais limpo usar delimitadores diferentes se você quiser usar caracteres de aspas em uma string entre aspas. Por exemplo "My name is \"$name\"" é muito melhor como qq{My name is "$name"}
  

use strict;
use warnings;

use XML::XPath;
use DBI;

my $xp = XML::XPath->new( filename => 'animals4.xml' );

my $dbh = DBI->connect(
   'DBI:mysql:test', 'user', 'pw',
   { RaiseError => 1, PrintError => 0}
) or die "Fehler beim Verbidungsaufbau zum MariaDB-Server: $DBI::err -< $DBI::errstr\n";

my $insert_animal = $dbh->prepare('INSERT INTO animal4 (name, category, type, size) VALUES (?, ?, ?, ?)');

for my $row1 ( $xp->findnodes('/database/row1s/row1') ) {

   my $name     = $row1->getAttribute('name');
   my $category = $row1->getAttribute('category');

   printf qq{Level --- row1 "name" gives: $name\n};

   my @row2 = $xp->findnodes('row2s/row2', $row1);

   if ( @row2 ) {
      for my $row2 ( @row2 ) {

         my $type = $row2->getAttribute('type');
         my $size = $row2->getAttribute('size');

         print qq{Level row2 "type" gives: $type\n};
         print qq{Level row2 "size" gives: $size\n};

         $insert_animal->execute($name, $category, $type, $size);
      }
   }
   else {
      $insert_animal->execute($name, $category, undef, undef);
   }
}

Level --- row1 "name" gives: fox
Level row2 "type" gives: 1
Level row2 "size" gives: 10
Level row2 "type" gives: 2
Level row2 "size" gives: 8
Level --- row1 "name" gives: horse
Level row2 "type" gives: 3
Level row2 "size" gives: 100
Level --- row1 "name" gives: bee
Level --- row1 "name" gives: wasp