Você está tentando usar tipos de nível de pacote em SQL simples, o que não é permitido. Os tipos declarados no pacote não são visíveis ou válidos fora do PL/SQL (ou mesmo em instruções SQL simples dentro do PL/SQL). Uma versão reduzida do que você está fazendo:
create or replace package types as
type my_rec_type is record (dummy dual.dummy%type);
type my_table_type is table of my_rec_type index by binary_integer;
end types;
/
create or replace package p42 as
function get_table return types.my_table_type;
end p42;
/
create or replace package body p42 as
function get_table return types.my_table_type is
my_table types.my_table_type;
begin
select * bulk collect into my_table from dual;
return my_table;
end get_table;
end p42;
/
select * from table(p42.get_table);
SQL Error: ORA-00902: invalid datatype
Mesmo dentro do pacote, se você tivesse uma procedure que tentasse usar a função table daria erro. Se você adicionou:
procedure test_proc is
begin
for r in (select * from table(get_table)) loop
null;
end loop;
end test_proc;
... a compilação do corpo do pacote falharia com
ORA-22905: cannot access rows from a non-nested table item . Você precisa declarar os tipos no nível do esquema, não em um pacote, portanto, usando o SQL
create type comando
:create type my_obj_type is object (dummy varchar2(1));
/
create type my_table_type is table of my_obj_type;
/
create or replace package p42 as
function get_table return my_table_type;
end p42;
/
create or replace package body p42 as
function get_table return my_table_type is
my_table my_table_type;
begin
select my_obj_type(dummy) bulk collect into my_table from dual;
return my_table;
end get_table;
end p42;
/
select * from table(p42.get_table);
DUMMY
-----
X
