No mínimo, você precisa consultar ALL_TAB_COLUMNS, não ALL_TABLES
DECLARE
match_count integer;
v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN
FOR t IN (SELECT owner, table_name, column_name FROM all_tab_columns) LOOP
EXECUTE IMMEDIATE
'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
' WHERE '||t.column_name||' = :1'
INTO match_count
USING v_search_string;
IF match_count > 0 THEN
dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
END IF;
END LOOP;
END;
/
Se você estiver procurando por uma string, no entanto, você quase certamente vai querer se restringir a procurar por colunas que possam armazenar uma string. Não faria sentido, por exemplo, pesquisar uma string em uma coluna DATE. E, a menos que você tenha um grande conhecimento a priori sobre o que uma coluna BLOB contém e a capacidade de analisar a formatação binária da coluna BLOB, não faria sentido pesquisar uma string em uma coluna BLOB. Dado isso, eu suspeito que você quer algo mais como
DECLARE
match_count integer;
v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN
FOR t IN (SELECT owner,
table_name,
column_name
FROM all_tab_columns
WHERE data_type in ('CHAR', 'VARCHAR2', 'NCHAR', 'NVARCHAR2',
'CLOB', 'NCLOB') )
LOOP
BEGIN
EXECUTE IMMEDIATE
'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
' WHERE '||t.column_name||' = :1'
INTO match_count
USING v_search_string;
IF match_count > 0 THEN
dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
END IF;
EXCEPTION
WHEN others THEN
dbms_output.put_line( 'Error encountered trying to read ' ||
t.column_name || ' from ' ||
t.owner || '.' || t.table_name );
END;
END LOOP;
END;
/
Claro, isso vai ser insanamente lento - você faria uma varredura completa em cada tabela uma vez para cada coluna de string na tabela. Com tabelas moderadamente grandes e um número moderado de colunas de strings, é provável que demore um pouco.
