Como criar arquivo de log no Oracle usando PL/SQL?

Você tem um programa PL/SQL e deseja registrar informações em um arquivo de texto de cada etapa do seu código. Aqui está um exemplo para criar um arquivo de log no Oracle usando PL/SQL.

Criar arquivo de log no Oracle usando exemplo de PL/SQL

A seguir está um procedimento PL/SQL para atualizar o preço do produto por um valor percentual passado como parâmetro. Além disso, ele registrará as informações de cada etapa que ocorre no programa. Observe que você deve ter um objeto de diretório criado no Oracle para gravar os arquivos. Confira este link para saber como criar um objeto de diretório no Oracle.

CREATE OR REPLACE PROCEDURE prod_price_update (increase_pct IN NUMBER)
IS
   f_file        UTL_FILE.file_type;
   v_file_name   VARCHAR2 (100);
BEGIN
   v_file_name := 'log_' || TO_CHAR (SYSDATE, 'yyyymmdd_HH24miss') || '.log';
   f_file := UTL_FILE.fopen ('LOG_FILES', v_file_name, 'w');
   UTL_FILE.put_line (f_file, 'Log file ' || v_file_name);
   UTL_FILE.new_line (f_file);
   UTL_FILE.put_line (
      f_file,
      'Job started at: ' || TO_CHAR (SYSDATE, 'dd-mm-yyyy HH24:mi:ss'));
   UTL_FILE.put_line (
      f_file,
      'Price increment percentage value: ' || increase_pct || '%');

   UPDATE products
      SET prod_list_price =
             prod_list_price + (prod_list_price * increase_pct / 100);

   UTL_FILE.put_line (f_file,
                      'Number of products updated:  ' || SQL%ROWCOUNT);

   COMMIT;
   UTL_FILE.put_line (f_file, 'Records committed.');
   UTL_FILE.put_line (
      f_file,
      'Job finished successfully at: '
      || TO_CHAR (SYSDATE, 'dd-mm-yyyy HH24:mi:ss'));
   UTL_FILE.fclose (f_file);
EXCEPTION
   WHEN OTHERS
   THEN
      IF UTL_FILE.is_open (f_file)
      THEN
         UTL_FILE.put_line (f_file, 'Job finished with errors: ' || SQLERRM);
         UTL_FILE.fclose (f_file);
      END IF;
END;

Teste o programa

BEGIN
   PROD_PRICE_UPDATE (12);
END;
/

A saída do arquivo de log (log_20180919_214756.log)

Log file log_20180919_214756.log

Job started at: 19-09-2018 21:47:56
Price increment percentage value: 12%
Number of products updated:  72
Records committed.
Job finished successfully at: 19-09-2018 21:47:57

Veja também:

Gravar arquivos CSV no Oracle usando PL/SQL