Como validar o número do cartão de crédito e identificar seu tipo usando PL/SQL?

Aqui estou dando um exemplo de função armazenada em PL/SQL para validar o número do cartão de crédito e identificar seu tipo, se é um cartão de crédito Visa, MasterCard ou American Express. Estou verificando o número do cartão de crédito usando o algoritmo LUHN que é usado para validar vários números de identificação. Se o número do cartão de crédito for válido, a função verifica seu tipo.

Exemplo de função PL/SQL para validar o número do cartão de crédito e seu tipo no Oracle

A função a seguir recebe um argumento como número de cartão de crédito e, em seguida, valida o número usando o algoritmo Luhn e retorna seu tipo. Atualmente, esta função PL/SQL suporta três tipos de Cartões de Crédito que são Visa, MasterCard e American Express. Você pode modificar para adicionar mais tipos de cartão de crédito. A função CHECK_LUHN_ALGO para verificar o número usando o algoritmo Luhn está escrita dentro da função VALIDATE_CC, portanto, se você quiser adicionar mais suporte a tipos de cartão, não será necessário alterar a função CHECK_LUHN_ALGO, altere apenas a parte principal da função VALIDATE_CC.

CREATE OR REPLACE FUNCTION validate_CC (cc_number IN VARCHAR2)
   RETURN VARCHAR2
IS
   v_ret_string   VARCHAR2 (100);

   FUNCTION check_luhn_algo (p_ccnumber VARCHAR2)
      RETURN NUMBER
   IS
      i          NUMBER;
      n_ntoi     SMALLINT;
      n_retval   SMALLINT;
      n_calc     NUMBER := 0;
      n_ntoc     NUMBER;
   BEGIN
      n_ntoc := LENGTH (p_ccnumber);

      FOR i IN 1 .. n_ntoc
      LOOP
         n_ntoi := TO_NUMBER (SUBSTR (p_ccnumber, n_ntoc + 1 - i, 1));

         n_calc :=
              n_calc
            + MOD (i, 2) * n_ntoi
            + MOD (i + 1, 2) * SIGN (-SIGN (n_ntoi - 4) + 1) * (2 * n_ntoi)
            +   MOD (i + 1, 2)
              * SIGN (SIGN (n_ntoi - 5) + 1)
              * (2 * n_ntoi - 9);
      END LOOP;

      n_retval := SIGN (MOD (n_calc, 10));

      RETURN n_retval;
   EXCEPTION
      WHEN OTHERS
      THEN
         RETURN 1;
   END check_luhn_algo;
BEGIN
   /* Credit card number is invalid if below funciton returns non zero value */
   IF check_luhn_algo (cc_number) != 0
   THEN
      v_ret_string := 'Not a valid Credit Card Number.';
      RETURN v_ret_string;
   ELSE
      v_ret_string := 'A Valid ';
   END IF;

   /* Credit card number is valid now check for its type */

   IF SUBSTR (cc_number, 1, 1) = '4'          /* check if it is a Visa card */
   THEN
      IF LENGTH (cc_number) = 13 OR LENGTH (cc_number) = 16
      THEN
         v_ret_string := v_ret_string || 'Visa Credit Card Number.';
      END IF;
   ELSIF SUBSTR (cc_number, 1, 2) BETWEEN 51 AND 55  /* check if master card*/
   THEN
      IF LENGTH (cc_number) = 16
      THEN
         v_ret_string := v_ret_string || 'MasterCard Credit Card Number.';
      END IF;
   ELSIF SUBSTR (cc_number, 1, 2) = 34 OR SUBSTR (cc_number, 1, 2) = 37 /* check if amex card */
   THEN
      IF LENGTH (cc_number) = 15
      THEN
         v_ret_string :=
            v_ret_string || 'American Express Credit Card Number.';
      END IF;
   ELSE
      v_ret_string := v_ret_string || 'But unable to identify its type.';
   END IF;

   RETURN v_ret_string;
EXCEPTION
   WHEN OTHERS
   THEN
      RETURN 'Error...';
END validate_CC;

Teste

Altere a string 4047xxxxxxxxxxxx abaixo pelo número do seu cartão de crédito Visa, MasterCard ou Amex para testar.

SET SERVEROUTPUT ON;

DECLARE
   RetVal      VARCHAR2 (100);
   CC_NUMBER   VARCHAR2 (100);
BEGIN
   CC_NUMBER := '4047xxxxxxxxxxxx';

   RetVal := VALIDATE_CC (CC_NUMBER);
   DBMS_OUTPUT.put_line (retval);
END;
/

Saída

A Valid Visa Credit Card Number.
PL/SQL procedure successfully completed.

Observação: Faça um teste completo antes de implementar no seu aplicativo.

Veja também:

Validar o endereço de e-mail usando PL/SQL no Oracle