Você pode dividir vários valores de uma única string com bastante facilidade. Digamos que você possa agrupar a string assim, usando uma vírgula para separar "colunas" e um ponto e vírgula para separar "linhas":
foo, 20120101, 26; bar, 20120612, 32
(Isso pressupõe que dois-pontos e ponto-e-vírgula não podem aparecer naturalmente nos dados; se puderem, você precisará escolher outros delimitadores.)
Você pode construir uma rotina de divisão como esta, que inclui uma coluna de saída que permite determinar a ordem em que o valor apareceu na string original:
CREATE FUNCTION dbo.SplitStrings
(
@List NVARCHAR(MAX),
@Delimiter NVARCHAR(255)
)
RETURNS TABLE
AS
RETURN (SELECT Number = ROW_NUMBER() OVER (ORDER BY Number),
Item FROM (SELECT Number, Item = LTRIM(RTRIM(SUBSTRING(@List, Number,
CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)))
FROM (SELECT ROW_NUMBER() OVER (ORDER BY [object_id])
FROM sys.all_objects) AS n(Number)
WHERE Number <= CONVERT(INT, LEN(@List))
AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
) AS y);
GO
Então você pode consultá-lo assim (para simplicidade e ilustração, estou lidando apenas com 3 propriedades, mas você pode extrapolar isso para 11 ou n):
DECLARE @x NVARCHAR(MAX); -- a parameter to your stored procedure
SET @x = N'foo, 20120101, 26; bar, 20120612, 32';
;WITH x AS
(
SELECT ID = s.Number, InnerID = y.Number, y.Item
-- parameter and "row" delimiter here:
FROM dbo.SplitStrings(@x, ';') AS s
-- output and "column" delimiter here:
CROSS APPLY dbo.SplitStrings(s.Item, ',') AS y
)
SELECT
prop1 = x.Item,
prop2 = x2.Item,
prop3 = x3.Item
FROM x
INNER JOIN x AS x2
ON x.InnerID = x2.InnerID - 1
AND x.ID = x2.ID
INNER JOIN x AS x3
ON x2.InnerID = x3.InnerID - 1
AND x2.ID = x3.ID
WHERE x.InnerID = 1
ORDER BY x.ID;
Resultados:
prop1 prop2 prop3
------ -------- -------
foo 20120101 26
bar 20120612 32
