Dividindo valores delimitados em uma coluna SQL em várias linhas

Se você estiver no SQL Server 2016+

Você pode usar o novo STRING_SPLIT função, sobre a qual eu escrevi aqui, e Brent Ozar escreveu aqui.

SELECT s.[message-id], f.value
  FROM dbo.SourceData AS s
  CROSS APPLY STRING_SPLIT(s.[recipient-address], ';') as f;

Se você ainda estiver em uma versão anterior ao SQL Server 2016

Crie uma função de divisão. Este é apenas um dos muitos exemplos que existem:

CREATE FUNCTION dbo.SplitStrings
(
    @List       NVARCHAR(MAX),
    @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
AS
    RETURN (SELECT Number = ROW_NUMBER() OVER (ORDER BY Number),
        Item FROM (SELECT Number, Item = LTRIM(RTRIM(SUBSTRING(@List, Number, 
        CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)))
    FROM (SELECT ROW_NUMBER() OVER (ORDER BY s1.[object_id])
        FROM sys.all_objects AS s1 CROSS APPLY sys.all_objects) AS n(Number)
    WHERE Number <= CONVERT(INT, LEN(@List))
        AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
    ) AS y);
GO

Eu discuti alguns outros aqui, aqui, e uma abordagem melhor do que dividir em primeiro lugar aqui.

Agora você pode extrapolar simplesmente por:

SELECT s.[message-id], f.Item
  FROM dbo.SourceData AS s
  CROSS APPLY dbo.SplitStrings(s.[recipient-address], ';') as f;

Também sugiro não colocar traços nos nomes das colunas. Isso significa que você sempre deve colocá-los entre [square brackets] .