REPLACE funciona nos seguintes tipos de dados:
Tanto search_string quanto replace_string, assim como char, podem ser qualquer um dos tipos de dadosCHAR,VARCHAR2,NCHAR,NVARCHAR2,CLOB, ouNCLOB.
Você optou por armazenar dados de caracteres como uma coleção de bytes (BLOB). Estes não podem ser trabalhados diretamente porque um BLOB não tem contexto e é apenas um número muito grande. Não pode ser convertido em caracteres sem seu input:você precisa de seu conjunto de caracteres para converter dados binários em texto.
Você terá que codificar a função
REPLACE você mesmo (usando DBMS_LOB.instr por exemplo) ou converta seus dados em um CLOB viável e use funções padrão no CLOB. Aconselho vivamente a alterar o tipo de dados da sua coluna. Isso evitará qualquer outro erro de conversão de conjunto de caracteres que você provavelmente encontrará no futuro.
Se você realmente deseja trabalhar com blobs, use funções como estas:
SQL> CREATE OR REPLACE FUNCTION convert_to_clob(l_blob BLOB) RETURN CLOB IS
2 l_clob CLOB;
3 l_dest_offset NUMBER := 1;
4 l_src_offset NUMBER := 1;
5 l_lang_context NUMBER := dbms_lob.default_lang_ctx;
6 l_warning NUMBER;
7 BEGIN
8 dbms_lob.createtemporary(l_clob, TRUE);
9 dbms_lob.converttoclob(dest_lob => l_clob,
10 src_blob => l_blob,
11 amount => dbms_lob.lobmaxsize,
12 dest_offset => l_dest_offset,
13 src_offset => l_src_offset,
14 blob_csid => nls_charset_id('AL32UTF8'),
15 lang_context => l_lang_context,
16 warning => l_warning);
17 RETURN l_clob;
18 END convert_to_clob;
19 /
Function created
SQL> CREATE OR REPLACE FUNCTION convert_to_blob(l_clob CLOB) RETURN BLOB IS
2 l_blob BLOB;
3 l_dest_offset NUMBER := 1;
4 l_src_offset NUMBER := 1;
5 l_lang_context NUMBER := dbms_lob.default_lang_ctx;
6 l_warning NUMBER;
7 BEGIN
8 dbms_lob.createtemporary(l_blob, TRUE);
9 dbms_lob.converttoblob(dest_lob => l_blob,
10 src_clob => l_clob,
11 amount => dbms_lob.lobmaxsize,
12 dest_offset => l_dest_offset,
13 src_offset => l_src_offset,
14 blob_csid => nls_charset_id('AL32UTF8'),
15 lang_context => l_lang_context,
16 warning => l_warning);
17 RETURN l_blob;
18 END convert_to_blob;
19 /
Function created
Você pode chamar essas funções diretamente do SQL:
SQL> UPDATE ape1_item_version
2 SET DYNAMIC_DATA = convert_to_blob(
3 REPLACE(convert_to_clob(DYNAMIC_DATA),
4 'Single period',
5 'Single period period set1')
6 )
7 WHERE NAME = 'PRIT ALL POOL for Duration Telephony 10_NA_G_V_H_N_Z2';
1 row updated
