Como verificar se o arquivo é imagem usando PL/SQL?

Neste post, estou compartilhando uma função com a qual você pode verificar se um arquivo é um arquivo de imagem ou não usando PL/SQL. O programa verificará o arquivo lendo seu cabeçalho e não o nome da extensão do arquivo. Atualmente, a função pode identificar três tipos de imagens que são JPG, PNG e GIF.

Função PL/SQL para verificar se o arquivo é um arquivo de imagem

A função PL/SQL a seguir lerá o cabeçalho do arquivo e retornará o tipo de imagem no tipo de dados varchar2. A função get_image_type recebe dois argumentos, e eles são os seguintes:

Objeto de diretório do Oracle (como i_dir) Aprenda a criar um objeto de diretório Oracle.
Nome do arquivo (como i_file) deve existir no diretório.

CREATE OR REPLACE FUNCTION get_image_type (i_dir    IN VARCHAR2,
                                           i_file   IN VARCHAR2)
   RETURN VARCHAR2
AS
   l_bfile       BFILE;
   l_blob        BLOB;
   l_file_type   VARCHAR2 (50);
BEGIN
   DBMS_LOB.createtemporary (l_blob, FALSE);
   l_bfile := BFILENAME (i_dir, i_file);
   DBMS_LOB.fileopen (l_bfile, DBMS_LOB.file_readonly);
   DBMS_LOB.loadfromfile (l_blob, l_bfile, DBMS_LOB.getlength (l_bfile));
   DBMS_LOB.fileclose (l_bfile);

   IF RAWTOHEX (DBMS_LOB.SUBSTR (l_blob, 8, 1)) = '89504E470D0A1A0A'
   THEN
      l_file_type := 'PNG';
   ELSIF DBMS_LOB.SUBSTR (l_blob, 3, 1) = '474946'
   THEN
      l_file_type := 'GIF';
   ELSIF RAWTOHEX (DBMS_LOB.SUBSTR (l_blob, 3, 1)) = 'FFD8FF'
   THEN
      l_file_type := 'JPG';
   ELSE
      l_file_type := 'The file is not an image.';
   END IF;

   RETURN l_file_type;
EXCEPTION
   WHEN OTHERS
   THEN
      IF DBMS_LOB.fileisopen (l_bfile) = 1
      THEN
         DBMS_LOB.fileclose (l_bfile);
      END IF;

      DBMS_LOB.freetemporary (l_blob);
      RETURN 'The file does not exists.';
END get_image_type;

Teste

No programa PL/SQL abaixo, altere o objeto de diretório MY_FILES Oracle com seu objeto de diretório e altere o nome do arquivo com o arquivo disponível no local do diretório MY_FILES.

SET SERVEROUTPUT ON;

DECLARE
   i_image_type   VARCHAR2 (50);
BEGIN
   i_image_type := get_image_type ('MY_FILES', 'oracle-logo-gif-to-use.gif');

   IF i_image_type IN ('JPG', 'GIF', 'PNG')
   THEN
      DBMS_OUTPUT.put_line ('The file is a valid ' || i_image_type || ' image.');
   ELSE
      DBMS_OUTPUT.put_line (i_image_type);
   END IF;
END;
/

Saída

The file is a valid GIF image.
PL/SQL procedure successfully completed.

Veja também:

Como inserir um arquivo na tabela Oracle usando PL/SQL?