Copiando dados de um arquivo para um CLOB no Oracle

O seguinte procedimento copy_file_data_to_clob() mostra como ler texto de um arquivo e
armazená-lo em um CLOB:
CREATE PROCEDURE copy_file_data_to_clob(
p_clob_id INTEGER,
p_directory VARCHAR2,
p_file_name VARCHAR2
) AS
v_file UTL_FILE.FILE_TYPE;
v_chars_read INTEGER;
v_dest_clob CLOB;
v_amount INTEGER :=32767;
v_char_buffer VARCHAR2(32767 );
BEGIN
-- insere um CLOB vazio
INSERT INTO clob_content(
id, clob_column
) VALUES (
p_clob_id, EMPTY_CLOB()
);
-- obtém o localizador LOB do CLOB
SELECT clob_column
INTO v_dest_clob
FROM clob_content
WHERE id =p_clob_id
FOR UPDATE;
-- abre o arquivo para leitura de texto (até v_amount caracteres por linha)
v_file :=UTL_FILE.FOPEN(p_directory, p_file_name, 'r', v_amount);
-- copy os dados do arquivo em v_dest_clob uma linha de cada vez
LOOP
BEGIN
-- lê uma linha do arquivo em v_char_buffer;
-- G ET_LINE() não copia o caractere de nova linha em
-- v_char_buffer
UTL_FILE.GET_LINE(v_file, v_char_buffer);
v_chars_read :=LENGTH(v_char_buffer);
-- anexa o line to v_dest_clob
DBMS_LOB.WRITEAPPEND(v_dest_clob, v_chars_read, v_char_buffer);
-- anexar uma nova linha a v_dest_clob porque v_char_buffer;
-- o valor ASCII para nova linha é 10, então CHR(10 ) retorna nova linha
DBMS_LOB.WRITEAPPEND(v_dest_clob, 1, CHR(10));
EXCEPTION
-- quando não houver mais dados no arquivo, saia
WHEN NO_DATA_FOUND THEN
EXIT;
END;
END LOOP;
-- fecha o arquivo
UTL_FILE.FCLOSE(v_file);
DBMS_OUTPUT.PUT_LINE('Copiar com sucesso concluído.');
END copy_file_data_to_clob;
/